• Home
• Felgo
• SpeechToText

SpeechToText

The SpeechToText singleton allows to convert recorded spoken audio into text. More...

• List of all members, including inherited members

Properties

• onDeviceRecognitionAvailable : bool
• recognitionActive : bool
• recognitionAvailable : bool

Signals

• speechToTextError(string error)
• speechToTextResult(string result, bool isFinal)

Methods

• void cancelSpeechToText()
• void startSpeechToText(string localeId, bool onDevice, bool partialResults)
• void stopSpeechToText()

Detailed Description

This object is available as a singleton type from all QML components when Felgo is imported via import Felgo 3.0. It is accessible with the name SpeechToText.

The SpeechToText singleton to convert recorded spoken audio into text, using the platform-native speech-to-text frameworks. It currently supports Android and iOS, both online transcription and on-device recognition (offline).

To start recording and transcription on supported devices on Android and iOS, call startSpeechToText().

 // Start speech to text recording in US English locale with online transcription
 SpeechToText.startSpeechToText("en-US")

After the recording starts, recognitionActive is true.

On Android, the recording automatically stops if there is no more spoken input, you get the results via the speechToTextResult signal.

To manually stop the recording, call stopSpeechToText().

If any errors occur, you get notified with speechToTextError.

Before starting the transcription, you should check if speech to text is supported on the current device with the properties recognitionAvailable or onDeviceRecognitionAvailable.

Example Usage

The following example shows speech to text in a textbox:

 import QtQuick
 import Felgo

 App {
   id: app

   property bool onDevice: false
   property string localeId: "en-US"

   Connections {
     target: SpeechToText

     onSpeechToTextResult: (result, isFinal) => {
       appTextEdit.text = result
     }

     onSpeechToTextError: error => {
       console.warn("Error:", error)
     }
   }

   NavigationStack {
     AppPage {
       title: qsTr("Speech To Text")

       Column {
         spacing: dp(20)

         width: parent.width - dp(40)
         anchors.centerIn: parent

         AppText {
           text: qsTr("Available: %1").arg(SpeechToText.recognitionAvailable)
         }

         AppText {
           text: qsTr("OnDevice available: %1").arg(SpeechToText.onDeviceRecognitionAvailable)
         }

         AppText {
           text: qsTr("Active: %1").arg(SpeechToText.recognitionActive)
         }

         AppText {
           text: qsTr("Locale: %1").arg(app.localeId)
         }

         Row {
           spacing: dp(20)

           AppText {
             id: onDeviceSwitch
             text: qsTr("On Device")
           }

           AppSwitch {
             anchors.verticalCenter: onDeviceSwitch.verticalCenter
             onCheckedChanged: {
               app.onDevice = !app.onDevice
             }
           }
         }

         Flow {
           spacing: dp(20)
           width: parent.width

           AppButton {
             text: qsTr("Start")

             onClicked: {
               appTextEdit.reset()
               SpeechToText.startSpeechToText(app.localeId, app.onDevice)
             }
           }

           AppButton {
             text: qsTr("Stop")

             onClicked: {
               SpeechToText.stopSpeechToText()
             }
           }

           AppButton {
             text: qsTr("Cancel")

             onClicked: {
               appTextEdit.reset()
               SpeechToText.cancelSpeechToText()
             }
           }
         }

         AppTextEdit {
           id: appTextEdit

           width: parent.width
           enabled: false

           function reset() {
             appTextEdit.text = ""
           }
         }
       }
     }
   }
 }

Integration steps

Some platforms require additional integration steps to use speech to text functionality.

iOS Integration

iOS Integration

To use SpeechToText on iOS devices, make sure to add the Speech framework to your project. Add the following lines to your project file:

 if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
   target_link_libraries(yourAppTarget PRIVATE "-framework Speech")
 endif()

You also need to add the 'NSMicrophoneUsageDescription' and 'NSSpeechRecognitionUsageDescription' keys to the Project-Info.plist file:

 <key>NSMicrophoneUsageDescription</key>
 <string>Use the microphone for Speech To Text</string>
 <key>NSSpeechRecognitionUsageDescription</key>
 <string>Use Speech To Text</string>

Android Integration

Open your AndroidManifest.xml file and make sure that the following permission is set:

 <uses-permission android:name="android.permission.RECORD_AUDIO"/>

Also add the following queries tag to the manifest block:

 <manifest ... >

   ...

   <!-- Speech To Text -->
   <queries>
       <intent>
           <action android:name="android.speech.RecognitionService" />
       </intent>
   </queries>

   ...

 </manifest>

Property Documentation

 // If SpeechToText.onDeviceRecognitionAvailable is true:
 SpeechToText.startSpeechToText("en-US", true)

 // If SpeechToText.recognitionAvailable is true:
 SpeechToText.startSpeechToText("en-US", false)

Signal Documentation

Method Documentation

 SpeechToText.startSpeechToText("en-US")

 SpeechToText.startSpeechToText("en-US", true)